nixo
/
gri3-wm
1
0
Fork 0
Code Issues Pull Requests Releases Wiki Activity

Implement parsing bar {} config blocks

next
Michael Stapelberg 2011-10-18 22:16:04 +01:00
parent d9f3a31cb7
commit 063b124e35
2 changed files with 266 additions and 3 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

48
src/cfgparse.l
View File

@ -37,6 +37,11 @@ int yycolumn = 1;
yy_push_state(EAT_WHITESPACE); \
} while (0)
#define BAR_DOUBLE_COLOR do { \
yy_push_state(BAR_COLOR); \
yy_push_state(BAR_COLOR); \
} while (0)
%}
EOL (\r?\n)
@ -50,7 +55,13 @@ EOL (\r?\n)
%s OUTPUT_COND
%s FOR_WINDOW_COND
%s EAT_WHITESPACE
%x BUFFER_LINE
%x BAR
%x BAR_MODE
%x BAR_POSITION
%x BAR_COLORS
%x BAR_COLOR
%%
@ -74,6 +85,37 @@ EOL (\r?\n)
yycolumn = 1;
}
/* This part of the lexer handles the bar {} blocks */
<BAR,BAR_MODE,BAR_POSITION,BAR_COLORS,BAR_COLOR>[ \t]+ { /* ignore whitespace */ ; }
<BAR>"{" { return '{'; }
<BAR>"}" { yy_pop_state(); return '}'; }
<BAR>^[ \t]*#[^\n]* { return TOKCOMMENT; }
<BAR>output { WS_STRING; return TOK_BAR_OUTPUT; }
<BAR>tray_output { WS_STRING; return TOK_BAR_TRAY_OUTPUT; }
<BAR>socket_path { WS_STRING; return TOK_BAR_SOCKET_PATH; }
<BAR>mode { yy_push_state(BAR_MODE); return TOK_BAR_MODE; }
<BAR_MODE>hide { yy_pop_state(); return TOK_BAR_HIDE; }
<BAR_MODE>dock { yy_pop_state(); return TOK_BAR_DOCK; }
<BAR>position { yy_push_state(BAR_POSITION); return TOK_BAR_POSITION; }
<BAR_POSITION>bottom { yy_pop_state(); return TOK_BAR_BOTTOM; }
<BAR_POSITION>top { yy_pop_state(); return TOK_BAR_TOP; }
<BAR>status_command { WS_STRING; return TOK_BAR_STATUS_COMMAND; }
<BAR>font { WS_STRING; return TOK_BAR_FONT; }
<BAR>workspace_buttons { return TOK_BAR_WORKSPACE_BUTTONS; }
<BAR>verbose { return TOK_BAR_VERBOSE; }
<BAR>colors { yy_push_state(BAR_COLORS); return TOK_BAR_COLORS; }
<BAR_COLORS>"{" { return '{'; }
<BAR_COLORS>"}" { yy_pop_state(); return '}'; }
<BAR_COLORS>background { yy_push_state(BAR_COLOR); return TOK_BAR_COLOR_BACKGROUND; }
<BAR_COLORS>statusline { yy_push_state(BAR_COLOR); return TOK_BAR_COLOR_STATUSLINE; }
<BAR_COLORS>focused_workspace { BAR_DOUBLE_COLOR; return TOK_BAR_COLOR_FOCUSED_WORKSPACE; }
<BAR_COLORS>active_workspace { BAR_DOUBLE_COLOR; return TOK_BAR_COLOR_ACTIVE_WORKSPACE; }
<BAR_COLORS>inactive_workspace { BAR_DOUBLE_COLOR; return TOK_BAR_COLOR_INACTIVE_WORKSPACE; }
<BAR_COLORS>urgent_workspace { BAR_DOUBLE_COLOR; return TOK_BAR_COLOR_URGENT_WORKSPACE; }
<BAR_COLOR>#[0-9a-fA-F]+ { yy_pop_state(); yylval.string = sstrdup(yytext+1); return HEXCOLOR; }
<BAR,BAR_COLORS,BAR_MODE,BAR_POSITION>[a-zA-Z]+ { yylval.string = sstrdup(yytext); return WORD; }
<FOR_WINDOW_COND>"]" { yy_pop_state(); return ']'; }
<ASSIGN_COND>"[" {
@ -93,13 +135,14 @@ EOL (\r?\n)
yylval.string = copy;
return STR;
}
<WANT_STRING>[^\n]+ { BEGIN(INITIAL); yylval.string = sstrdup(yytext); return STR; }
<WANT_STRING>[^\n]+ { yy_pop_state(); yylval.string = sstrdup(yytext); return STR; }
<OUTPUT_COND>[a-zA-Z0-9_-]+ { yylval.string = sstrdup(yytext); return OUTPUT; }
^[ \t]*#[^\n]* { return TOKCOMMENT; }
<COLOR_COND>[0-9a-fA-F]+ { yylval.string = sstrdup(yytext); return HEX; }
<ASSIGN_TARGET_COND>[ \t]*→[ \t]* { BEGIN(WANT_STRING); }
<ASSIGN_TARGET_COND>[ \t]+ { BEGIN(WANT_STRING); }
[0-9]+ { yylval.number = atoi(yytext); return NUMBER; }
bar { yy_push_state(BAR); return TOK_BAR; }
mode { return TOKMODE; }
bind { yy_push_state(WANT_STRING); yy_push_state(EAT_WHITESPACE); yy_push_state(EAT_WHITESPACE); return TOKBINDCODE; }
bindcode { yy_push_state(WANT_STRING); yy_push_state(EAT_WHITESPACE); yy_push_state(EAT_WHITESPACE); return TOKBINDCODE; }
@ -179,10 +222,9 @@ con_id { yy_push_state(WANT_QSTRING); return TOK_CON_ID
con_mark { yy_push_state(WANT_QSTRING); return TOK_MARK; }
title { yy_push_state(WANT_QSTRING); return TOK_TITLE; }
{EOL} {
<*>{EOL} {
FREE(context->line_copy);
context->line_number++;
BEGIN(INITIAL);
yy_push_state(BUFFER_LINE);
}
<BINDSYM_COND>[ \t]+ { BEGIN(WANT_STRING); }

221
src/cfgparse.y
View File

@ -14,6 +14,7 @@
static pid_t configerror_pid = -1;
static Match current_match;
static Barconfig current_bar;
typedef struct yy_buffer_state *YY_BUFFER_STATE;
extern int yylex(struct context *context);
@ -587,6 +588,7 @@ void parse_file(const char *f) {
%token <string> STR "<string>"
%token <string> STR_NG "<string (non-greedy)>"
%token <string> HEX "<hex>"
%token <string> HEXCOLOR "#<hex>"
%token <string> OUTPUT "<RandR output>"
%token TOKBINDCODE
%token TOKTERMINAL
@ -610,6 +612,7 @@ void parse_file(const char *f) {
%token <color> TOKCOLOR
%token TOKARROW "→"
%token TOKMODE "mode"
%token TOK_BAR "bar"
%token TOK_ORIENTATION "default_orientation"
%token TOK_HORIZ "horizontal"
%token TOK_VERT "vertical"
@ -634,6 +637,27 @@ void parse_file(const char *f) {
%token TOK_LEAVE_FULLSCREEN "leave_fullscreen"
%token TOK_FOR_WINDOW "for_window"
%token TOK_BAR_OUTPUT "output (bar)"
%token TOK_BAR_TRAY_OUTPUT "tray_output"
%token TOK_BAR_SOCKET_PATH "socket_path"
%token TOK_BAR_MODE "mode"
%token TOK_BAR_HIDE "hide"
%token TOK_BAR_DOCK "dock"
%token TOK_BAR_POSITION "position"
%token TOK_BAR_BOTTOM "bottom"
%token TOK_BAR_TOP "top"
%token TOK_BAR_STATUS_COMMAND "status_command"
%token TOK_BAR_FONT "font"
%token TOK_BAR_WORKSPACE_BUTTONS "workspace_buttons"
%token TOK_BAR_VERBOSE "verbose"
%token TOK_BAR_COLORS "colors"
%token TOK_BAR_COLOR_BACKGROUND "background"
%token TOK_BAR_COLOR_STATUSLINE "statusline"
%token TOK_BAR_COLOR_FOCUSED_WORKSPACE "focused_workspace"
%token TOK_BAR_COLOR_ACTIVE_WORKSPACE "active_workspace"
%token TOK_BAR_COLOR_INACTIVE_WORKSPACE "inactive_workspace"
%token TOK_BAR_COLOR_URGENT_WORKSPACE "urgent_workspace"
%token TOK_MARK "mark"
%token TOK_CLASS "class"
%token TOK_INSTANCE "instance"
@ -655,6 +679,8 @@ void parse_file(const char *f) {
%type <number> colorpixel
%type <number> bool
%type <number> popup_setting
%type <number> bar_position_position
%type <number> bar_mode_mode
%type <string> command
%type <string> word_or_number
%type <string> optional_workspace_name
@ -672,6 +698,7 @@ line:
bindline
| for_window
| mode
| bar
| floating_modifier
| orientation
| workspace_layout
@ -902,6 +929,200 @@ modeline:
}
;
bar:
TOK_BAR '{' barlines '}'
{
printf("\t new bar configuration finished, saving.\n");
/* Generate a unique ID for this bar */
current_bar.id = sstrdup("foo"); /* TODO */
/* Copy the current (static) structure into a dynamically allocated
* one, then cleanup our static one. */
Barconfig *bar_config = scalloc(sizeof(Barconfig));
memcpy(bar_config, &current_bar, sizeof(Barconfig));
TAILQ_INSERT_TAIL(&barconfigs, bar_config, configs);
memset(&current_bar, '\0', sizeof(Barconfig));
}
;
barlines:
/* empty */
| barlines barline
;
barline:
comment
| bar_status_command
| bar_output
| bar_tray_output
| bar_position
| bar_mode
| bar_font
| bar_workspace_buttons
| bar_verbose
| bar_socket_path
| bar_colors
| bar_color_background
| bar_color_statusline
| bar_color_focused_workspace
| bar_color_active_workspace
| bar_color_inactive_workspace
| bar_color_urgent_workspace
;
bar_status_command:
TOK_BAR_STATUS_COMMAND STR
{
DLOG("should add status command %s\n", $2);
FREE(current_bar.status_command);
current_bar.status_command = $2;
}
;
bar_output:
TOK_BAR_OUTPUT STR
{
DLOG("bar output %s\n", $2);
int new_outputs = current_bar.num_outputs + 1;
current_bar.outputs = srealloc(current_bar.outputs, sizeof(char*) * new_outputs);
current_bar.outputs[current_bar.num_outputs] = $2;
current_bar.num_outputs = new_outputs;
}
;
bar_tray_output:
TOK_BAR_TRAY_OUTPUT STR
{
DLOG("tray %s\n", $2);
FREE(current_bar.tray_output);
current_bar.tray_output = $2;
}
;
bar_position:
TOK_BAR_POSITION bar_position_position
{
DLOG("position %d\n", $2);
current_bar.position = $2;
}
;
bar_position_position:
TOK_BAR_TOP { $$ = P_TOP; }
| TOK_BAR_BOTTOM { $$ = P_BOTTOM; }
;
bar_mode:
TOK_BAR_MODE bar_mode_mode
{
DLOG("mode %d\n", $2);
current_bar.mode = $2;
}
;
bar_mode_mode:
TOK_BAR_HIDE { $$ = M_HIDE; }
| TOK_BAR_DOCK { $$ = M_DOCK; }
;
bar_font:
TOK_BAR_FONT STR
{
DLOG("font %s\n", $2);
FREE(current_bar.font);
current_bar.font = $2;
}
;
bar_workspace_buttons:
TOK_BAR_WORKSPACE_BUTTONS bool
{
DLOG("workspace_buttons = %d\n", $2);
/* We store this inverted to make the default setting right when
* initializing the struct with zero. */
current_bar.hide_workspace_buttons = !($2);
}
;
bar_verbose:
TOK_BAR_VERBOSE bool
{
DLOG("verbose = %d\n", $2);
current_bar.verbose = $2;
}
;
bar_socket_path:
TOK_BAR_SOCKET_PATH STR
{
DLOG("socket_path = %s\n", $2);
FREE(current_bar.socket_path);
current_bar.socket_path = $2;
}
;
bar_colors:
TOK_BAR_COLORS '{' barlines '}'
{
/* At the moment, the TOK_BAR_COLORS token is only to make the config
* friendlier for humans. We might change this in the future if it gets
* more complex. */
}
;
bar_color_background:
TOK_BAR_COLOR_BACKGROUND HEXCOLOR
{
DLOG("background = %s\n", $2);
current_bar.colors.background = $2;
}
;
bar_color_statusline:
TOK_BAR_COLOR_STATUSLINE HEXCOLOR
{
DLOG("statusline = %s\n", $2);
current_bar.colors.statusline = $2;
}
;
bar_color_focused_workspace:
TOK_BAR_COLOR_FOCUSED_WORKSPACE HEXCOLOR HEXCOLOR
{
DLOG("focused_ws = %s and %s\n", $2, $3);
current_bar.colors.focused_workspace_text = $2;
current_bar.colors.focused_workspace_bg = $3;
}
;
bar_color_active_workspace:
TOK_BAR_COLOR_ACTIVE_WORKSPACE HEXCOLOR HEXCOLOR
{
DLOG("active_ws = %s and %s\n", $2, $3);
current_bar.colors.active_workspace_text = $2;
current_bar.colors.active_workspace_bg = $3;
}
;
bar_color_inactive_workspace:
TOK_BAR_COLOR_INACTIVE_WORKSPACE HEXCOLOR HEXCOLOR
{
DLOG("inactive_ws = %s and %s\n", $2, $3);
current_bar.colors.inactive_workspace_text = $2;
current_bar.colors.inactive_workspace_bg = $3;
}
;
bar_color_urgent_workspace:
TOK_BAR_COLOR_URGENT_WORKSPACE HEXCOLOR HEXCOLOR
{
DLOG("urgent_ws = %s and %s\n", $2, $3);
current_bar.colors.urgent_workspace_text = $2;
current_bar.colors.urgent_workspace_bg = $3;
}
;
floating_modifier:
TOKFLOATING_MODIFIER binding_modifiers
{