nixo
/
guix-devel
1
0
Fork 0
Code Issues Pull Requests Releases Wiki Activity

build-system: Add cargo build system. 

* guix/build-system/cargo.scm: New file.
* guix/build/cargo-build-system.scm: New file.
* Makefile.am (MODULES): Add files.
This commit is contained in:
David Craven 2016-09-22 14:58:31 +02:00
parent 7ab3ea4266
commit 4b3cb7f4bc
No known key found for this signature in database
GPG Key ID: C5E051C79C0BECDB
3 changed files with 256 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

2
Makefile.am
View File

@ -61,6 +61,7 @@ MODULES = \
guix/zlib.scm \ guix/zlib.scm \
guix/build-system.scm \ guix/build-system.scm \
guix/build-system/ant.scm \ guix/build-system/ant.scm \
guix/build-system/cargo.scm \
guix/build-system/cmake.scm \ guix/build-system/cmake.scm \
guix/build-system/emacs.scm \ guix/build-system/emacs.scm \
guix/build-system/asdf.scm \ guix/build-system/asdf.scm \
@ -83,6 +84,7 @@ MODULES = \
guix/ui.scm \ guix/ui.scm \
guix/build/ant-build-system.scm \ guix/build/ant-build-system.scm \
guix/build/download.scm \ guix/build/download.scm \
guix/build/cargo-build-system.scm \
guix/build/cmake-build-system.scm \ guix/build/cmake-build-system.scm \
guix/build/emacs-build-system.scm \ guix/build/emacs-build-system.scm \
guix/build/asdf-build-system.scm \ guix/build/asdf-build-system.scm \

150
guix/build-system/cargo.scm Normal file
View File

@ -0,0 +1,150 @@
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2013, 2014, 2015, 2016 Ludovic Courtès <ludo@gnu.org>
;;; Copyright © 2013 Andreas Enge <andreas@enge.fr>
;;; Copyright © 2013 Nikita Karetnikov <nikita@karetnikov.org>
;;; Copyright © 2016 David Craven <david@craven.ch>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (guix build-system cargo)
#:use-module (guix search-paths)
#:use-module (guix store)
#:use-module (guix utils)
#:use-module (guix derivations)
#:use-module (guix packages)
#:use-module (guix build-system)
#:use-module (guix build-system gnu)
#:use-module (ice-9 match)
#:use-module (srfi srfi-26)
#:export (cargo-build-system
crate-url
crate-url?
crate-uri))
(define crate-url "https://crates.io/api/v1/crates/")
(define crate-url? (cut string-prefix? crate-url <>))
(define (crate-uri name version)
"Return a URI string for the crate package hosted at crates.io corresponding
to NAME and VERSION."
(string-append crate-url name "/" version "/download"))
(define (default-cargo)
"Return the default Cargo package."
;; Lazily resolve the binding to avoid a circular dependency.
(let ((rust (resolve-interface '(gnu packages rust))))
;; FIXME: Package cargo and replace cargo-bootstrap with cargo.
(module-ref rust 'cargo-bootstrap)))
(define (default-rustc)
"Return the default Rustc package."
;; Lazily resolve the binding to avoid a circular dependency.
(let ((rust (resolve-interface '(gnu packages rust))))
(module-ref rust 'rustc)))
(define %cargo-build-system-modules
;; Build-side modules imported by default.
`((guix build cargo-build-system)
,@%gnu-build-system-modules))
(define* (cargo-build store name inputs
#:key
(tests? #t)
(test-target #f)
(configure-flags #f)
(phases '(@ (guix build cargo-build-system)
%standard-phases))
(outputs '("out"))
(search-paths '())
(system (%current-system))
(guile #f)
(imported-modules %cargo-build-system-modules)
(modules '((guix build cargo-build-system)
(guix build utils))))
"Build SOURCE using CARGO, and with INPUTS."
(define builder
`(begin
(use-modules ,@modules)
(cargo-build #:name ,name
#:source ,(match (assoc-ref inputs "source")
(((? derivation? source))
(derivation->output-path source))
((source)
source)
(source
source))
#:system ,system
#:test-target ,test-target
#:tests? ,tests?
#:phases ,phases
#:outputs %outputs
#:search-paths ',(map search-path-specification->sexp
search-paths)
#:inputs %build-inputs)))
(define guile-for-build
(match guile
((? package?)
(package-derivation store guile system #:graft? #f))
(#f ; the default
(let* ((distro (resolve-interface '(gnu packages commencement)))
(guile (module-ref distro 'guile-final)))
(package-derivation store guile system #:graft? #f)))))
(build-expression->derivation store name builder
#:inputs inputs
#:system system
#:modules imported-modules
#:outputs outputs
#:guile-for-build guile-for-build))
(define* (lower name
#:key source inputs native-inputs outputs system target
(cargo (default-cargo))
(rustc (default-rustc))
#:allow-other-keys
#:rest arguments)
"Return a bag for NAME."
(define private-keywords
'(#:source #:target #:cargo #:rustc #:inputs #:native-inputs))
(and (not target) ;; TODO: support cross-compilation
(bag
(name name)
(system system)
(target target)
(host-inputs `(,@(if source
`(("source" ,source))
'())
,@inputs
;; Keep the standard inputs of 'gnu-build-system'
,@(standard-packages)))
(build-inputs `(("cargo" ,cargo)
("rustc" ,rustc)
,@native-inputs))
(outputs outputs)
(build cargo-build)
(arguments (strip-keyword-arguments private-keywords arguments)))))
(define cargo-build-system
(build-system
(name 'cargo)
(description
"Cargo build system, to build Rust crates")
(lower lower)))

104
guix/build/cargo-build-system.scm Normal file
View File

@ -0,0 +1,104 @@
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2016 David Craven <david@craven.ch>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (guix build cargo-build-system)
#:use-module ((guix build gnu-build-system) #:prefix gnu:)
#:use-module (guix build utils)
#:use-module (ice-9 ftw)
#:use-module (ice-9 format)
#:use-module (ice-9 match)
#:use-module (srfi srfi-1)
#:use-module (srfi srfi-26)
#:export (%standard-phases
cargo-build))
;; Commentary:
;;
;; Builder-side code of the standard Rust package build procedure.
;;
;; Code:
;; FIXME: Needs to be parsed from url not package name.
(define (package-name->crate-name name)
"Return the crate name of NAME."
(match (string-split name #\-)
(("rust" rest ...)
(string-join rest "-"))
(_ #f)))
(define* (configure #:key inputs #:allow-other-keys)
"Replace Cargo.toml [dependencies] section with guix inputs."
(let ((port (open-file "Cargo.toml" "a" #:encoding "utf-8")))
(format port "~%[replace]~%")
(for-each
(match-lambda
((name . path)
(let ((crate (package-name->crate-name name)))
(when (and crate path)
(match (string-split (basename path) #\-)
((_ ... version)
(format port "\"~a:~a\" = { path = \"~a/rustsrc\" }~%"
crate version path)))))))
inputs)
(close-port port))
#t)
(define* (build #:key (cargo-build-flags '("--release" "--frozen"))
#:allow-other-keys)
"Build a given Cargo package."
(zero? (apply system* `("cargo" "build" ,@cargo-build-flags))))
(define* (check #:key tests? #:allow-other-keys)
"Run tests for a given Cargo package."
(when tests?
(zero? (system* "cargo" "test"))))
(define* (install #:key inputs outputs #:allow-other-keys)
"Install a given Cargo package."
(let* ((out (assoc-ref outputs "out"))
(src (assoc-ref inputs "source"))
(bin (string-append out "/bin"))
(rsrc (string-append out "/rustsrc")))
(mkdir-p rsrc)
;; Rust doesn't have a stable ABI yet. Because of this
;; Cargo doesn't have a search path for binaries yet.
;; Until this changes we are working around this by
;; distributing crates as source and replacing
;; references in Cargo.toml with store paths.
(copy-recursively "src" (string-append rsrc "/src"))
(install-file "Cargo.toml" rsrc)
;; When the package includes executables we install
;; it using cargo install. This fails when the crate
;; doesn't contain an executable.
(system* "cargo" "install" "--root" bin)
#t))
(define %standard-phases
;; 'configure' phase is not needed.
(modify-phases gnu:%standard-phases
(replace 'configure configure)
(replace 'build build)
(replace 'check check)
(replace 'install install)))
(define* (cargo-build #:key inputs (phases %standard-phases)
#:allow-other-keys #:rest args)
"Build the given Cargo package, applying all of PHASES in order."
(apply gnu:gnu-build #:inputs inputs #:phases phases args))
;;; cargo-build-system.scm ends here