nixo
/
guix-devel
1
0
Fork 0
Code Issues Pull Requests Releases Wiki Activity

build: Add R build system. 

* guix/build-system/r.scm: New file.
* guix/build/r-build-system: New file.
* Makefile.am (MODULES): Add new files.
* doc/guix.texi (Build Systems): Document r-build-system.
master
Ricardo Wurmus 2015-07-31 14:47:34 +02:00
parent e1248602f9
commit f8f3bef6aa
4 changed files with 258 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

2
Makefile.am
View File

@ -58,6 +58,7 @@ MODULES = \
guix/build-system/perl.scm \
guix/build-system/python.scm \
guix/build-system/waf.scm \
guix/build-system/r.scm \
guix/build-system/ruby.scm \
guix/build-system/trivial.scm \
guix/ftp-client.scm \
@ -77,6 +78,7 @@ MODULES = \
guix/build/gnu-dist.scm \
guix/build/perl-build-system.scm \
guix/build/python-build-system.scm \
guix/build/r-build-system.scm \
guix/build/ruby-build-system.scm \
guix/build/waf-build-system.scm \
guix/build/haskell-build-system.scm \

10
doc/guix.texi
View File

@ -2491,6 +2491,16 @@ passes flags specified by the @code{#:make-maker-flags} or
Which Perl package is used can be specified with @code{#:perl}.
@end defvr
@defvr {Scheme Variable} r-build-system
This variable is exported by @code{(guix build-system r)}. It
implements the build procedure used by @uref{http://r-project.org, R}
packages, which essentially is little more than running @code{R CMD
INSTALL --library=/gnu/store/@dots{}} in an environment where
@code{R_LIBS_SITE} contains the paths to all R package inputs. Tests
are run after installation using the R function
@code{tools::testInstalledPackage}.
@end defvr
@defvr {Scheme Variable} ruby-build-system
This variable is exported by @code{(guix build-system ruby)}. It
implements the RubyGems build procedure used by Ruby packages, which

134
guix/build-system/r.scm Normal file
View File

@ -0,0 +1,134 @@
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2015 Ricardo Wurmus <rekado@elephly.net>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (guix build-system r)
#:use-module (guix store)
#:use-module (guix utils)
#:use-module (guix packages)
#:use-module (guix derivations)
#:use-module (guix search-paths)
#:use-module (guix build-system)
#:use-module (guix build-system gnu)
#:use-module (ice-9 match)
#:use-module (srfi srfi-26)
#:export (%r-build-system-modules
r-build
r-build-system))
;; Commentary:
;;
;; Standard build procedure for R packages.
;;
;; Code:
(define %r-build-system-modules
;; Build-side modules imported by default.
`((guix build r-build-system)
,@%gnu-build-system-modules))
(define (default-r)
"Return the default R package."
;; Lazily resolve the binding to avoid a circular dependency.
(let ((r-mod (resolve-interface '(gnu packages statistics))))
(module-ref r-mod 'r)))
(define* (lower name
#:key source inputs native-inputs outputs system target
(r (default-r))
#:allow-other-keys
#:rest arguments)
"Return a bag for NAME."
(define private-keywords
'(#:source #:target #:inputs #:native-inputs))
(and (not target) ;XXX: no cross-compilation
(bag
(name name)
(system system)
(host-inputs `(,@(if source
`(("source" ,source))
'())
,@inputs
;; Keep the standard inputs of 'gnu-build-system'.
,@(standard-packages)))
(build-inputs `(("r" ,r)
,@native-inputs))
(outputs outputs)
(build r-build)
(arguments (strip-keyword-arguments private-keywords arguments)))))
(define* (r-build store name inputs
#:key
(tests? #t)
(test-target "tests")
(configure-flags ''())
(phases '(@ (guix build r-build-system)
%standard-phases))
(outputs '("out"))
(search-paths '())
(system (%current-system))
(guile #f)
(imported-modules %r-build-system-modules)
(modules '((guix build r-build-system)
(guix build utils))))
"Build SOURCE with INPUTS."
(define builder
`(begin
(use-modules ,@modules)
(r-build #:name ,name
#:source ,(match (assoc-ref inputs "source")
(((? derivation? source))
(derivation->output-path source))
((source)
source)
(source
source))
#:configure-flags ,configure-flags
#:system ,system
#:tests? ,tests?
#:test-target ,test-target
#:phases ,phases
#:outputs %outputs
#:search-paths ',(map search-path-specification->sexp
search-paths)
#:inputs %build-inputs)))
(define guile-for-build
(match guile
((? package?)
(package-derivation store guile system #:graft? #f))
(#f ; the default
(let* ((distro (resolve-interface '(gnu packages commencement)))
(guile (module-ref distro 'guile-final)))
(package-derivation store guile system #:graft? #f)))))
(build-expression->derivation store name builder
#:inputs inputs
#:system system
#:modules imported-modules
#:outputs outputs
#:guile-for-build guile-for-build))
(define r-build-system
(build-system
(name 'r)
(description "The standard R build system")
(lower lower)))
;;; r.scm ends here

112
guix/build/r-build-system.scm Normal file
View File

@ -0,0 +1,112 @@
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2015 Ricardo Wurmus <rekado@elephly.net>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (guix build r-build-system)
#:use-module ((guix build gnu-build-system) #:prefix gnu:)
#:use-module (guix build utils)
#:use-module (ice-9 match)
#:use-module (ice-9 ftw)
#:use-module (ice-9 popen)
#:use-module (srfi srfi-1)
#:use-module (srfi srfi-26)
#:export (%standard-phases
r-build))
;; Commentary:
;;
;; Builder-side code of the standard build procedure for R packages.
;;
;; Code:
(define (invoke-r command params)
(zero? (apply system* "R" "CMD" command params)))
(define (pipe-to-r command params)
(let ((port (apply open-pipe* OPEN_WRITE "R" params)))
(display command port)
(zero? (status:exit-val (close-pipe port)))))
(define (generate-site-path inputs)
(string-join (map (match-lambda
((_ . path)
(string-append path "/site-library")))
;; Restrict to inputs beginning with "r-".
(filter (match-lambda
((name . _)
(string-prefix? "r-" name)))
inputs))
":"))
(define* (check #:key test-target inputs outputs tests? #:allow-other-keys)
"Run the test suite of a given R package."
(let* ((libdir (string-append (assoc-ref outputs "out") "/site-library/"))
;; R package names are case-sensitive and cannot be derived from the
;; Guix package name. The exact package name is required as an
;; argument to ‘tools::testInstalledPackage’, which runs the tests
;; for a package given its name and the path to the “library” (a
;; location for a collection of R packages) containing it.
;; Since there can only be one R package in any collection (=
;; “library”), the name of the only directory in the collection path
;; is the original name of the R package.
(pkg-name (car (scandir libdir (negate (cut member <> '("." ".."))))))
(testdir (string-append libdir pkg-name "/" test-target))
(site-path (string-append libdir ":" (generate-site-path inputs))))
(if (and tests? (file-exists? testdir))
(begin
(setenv "R_LIBS_SITE" site-path)
(pipe-to-r (string-append "tools::testInstalledPackage(\"" pkg-name "\", "
"lib.loc = \"" libdir "\")")
'("--no-save" "--slave")))
#t)))
(define* (install #:key outputs inputs (configure-flags '())
#:allow-other-keys)
"Install a given R package."
(let* ((out (assoc-ref outputs "out"))
(site-library (string-append out "/site-library/"))
(params (append configure-flags
(list "--install-tests"
(string-append "--library=" site-library)
".")))
(site-path (string-append site-library ":"
(generate-site-path inputs))))
;; If dependencies cannot be found at install time, R will refuse to
;; install the package.
(setenv "R_LIBS_SITE" site-path)
;; Some R packages contain a configure script for which the CONFIG_SHELL
;; variable should be set.
(setenv "CONFIG_SHELL" (which "bash"))
(mkdir-p site-library)
(invoke-r "INSTALL" params)))
(define %standard-phases
(modify-phases gnu:%standard-phases
(delete 'configure)
(delete 'build)
(delete 'check) ; tests must be run after installation
(replace 'install install)
(add-after 'install 'check check)))
(define* (r-build #:key inputs (phases %standard-phases)
#:allow-other-keys #:rest args)
"Build the given R package, applying all of PHASES in order."
(apply gnu:gnu-build #:inputs inputs #:phases phases args))
;;; r-build-system.scm ends here