system: grub: Use Guile-{RSVG,Cairo} instead of Inkscape + ImageMagick.

Based on a suggestion by Andy Wingo at
<https://lists.gnu.org/archive/html/guix-devel/2015-08/msg00753.html>.

* gnu/build/svg.scm: New file.
* gnu/local.mk (GNU_SYSTEM_MODULES): Add it.
* gnu/system/grub.scm (svg->png): Add #:width and #:height.  Rewrite to
use (gnu build svg).
(resize-image): Remove.
(grub-background-image): Adjust accordingly.

gnu/build/svg.scm

@@ -0,0 +1,69 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2016 Ludovic Courtès <ludo@gnu.org>
+;;; Copyright © 2015 Andy Wingo <wingo@igalia.com>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu build svg)
+  #:use-module (srfi srfi-11)
+  #:export (svg->png))
+
+;; We need Guile-RSVG and Guile-Cairo.  Load them lazily, at run time, to
+;; allow compilation to proceed.
+(module-use! (current-module) (resolve-interface '(rsvg)))
+(module-use! (current-module) (resolve-interface '(cairo)))
+
+(define* (downscaled-surface surface
+                             #:key
+                             source-width source-height
+                             width height)
+  "Return a new rendering context where SURFACE is scaled to WIDTH x HEIGHT."
+  (let ((cr (cairo-create (cairo-image-surface-create 'argb32
+                                                      width height))))
+    (cairo-scale cr (/ width source-width) (/ height source-height))
+    (cairo-set-source-surface cr surface 0 0)
+    (cairo-pattern-set-filter (cairo-get-source cr) 'best)
+    (cairo-rectangle cr 0 0 source-width source-height)
+    (cairo-fill cr)
+    cr))
+
+(define* (svg->png in-svg out-png
+                   #:key width height)
+  "Render the file at IN-SVG as a PNG file in OUT-PNG.  When WIDTH and HEIGHT
+are provided, use them as the dimensions of OUT-PNG; otherwise preserve the
+dimensions of IN-SVG."
+  (define svg
+    (rsvg-handle-new-from-file in-svg))
+
+  (let-values (((origin-width origin-height)
+                (rsvg-handle-get-dimensions svg)))
+    (let* ((surf (cairo-image-surface-create 'argb32
+                                             origin-width origin-height))
+           (cr   (cairo-create surf)))
+      (rsvg-handle-render-cairo svg cr)
+      (cairo-surface-flush surf)
+      (let ((cr (if (and width height
+                         (not (= width origin-width))
+                         (not (= height origin-height)))
+                    (downscaled-surface surf
+                                        #:source-width origin-width
+                                        #:source-height origin-height
+                                        #:width width
+                                        #:height height)
+                    cr)))
+        (cairo-surface-write-to-png (cairo-get-target cr) out-png)))))
+
+;;; svg.scm ends here

gnu/local.mk

@@ -431,6 +431,7 @@ GNU_SYSTEM_MODULES =				\
   %D%/build/linux-initrd.scm			\
   %D%/build/linux-modules.scm			\
   %D%/build/marionette.scm			\
+  %D%/build/svg.scm				\
   %D%/build/vm.scm				\
 						\
   %D%/tests.scm					\

gnu/system/grub.scm

@@ -27,9 +27,8 @@
   #:use-module (gnu artwork)
   #:use-module (gnu system file-systems)
   #:autoload   (gnu packages grub) (grub)
-  #:autoload   (gnu packages inkscape) (inkscape)
-  #:autoload   (gnu packages imagemagick) (imagemagick)
   #:autoload   (gnu packages compression) (gzip)
+  #:autoload   (gnu packages gtk) (guile-cairo guile-rsvg)
   #:use-module (ice-9 match)
   #:use-module (ice-9 regex)
   #:use-module (srfi srfi-1)
@@ -132,25 +131,23 @@ object denoting a file name."
 ;;; Background image & themes.
 ;;;
 
-(define (svg->png svg)
+(define* (svg->png svg #:key width height)
-  "Build a PNG from SVG."
+  "Build a PNG of HEIGHT x WIDTH from SVG."
-  ;; Don't use #:local-build? so that it's substitutable.
   (gexp->derivation "grub-image.png"
-                    #~(zero?
+                    (with-imported-modules '((gnu build svg))
-                       (system* (string-append #$inkscape "/bin/inkscape")
+                      #~(begin
-                                "--without-gui"
+                          ;; We need these two libraries.
-                                (string-append "--export-png=" #$output)
+                          (add-to-load-path (string-append #$guile-rsvg
-                                #$svg))))
+                                                           "/share/guile/site/"
+                                                           (effective-version)))
+                          (add-to-load-path (string-append #$guile-cairo
+                                                           "/share/guile/site/"
+                                                           (effective-version)))
 
-(define (resize-image image width height)
+                          (use-modules (gnu build svg))
-  "Resize IMAGE to WIDTHxHEIGHT."
+                          (svg->png #$svg #$output
-  ;; Don't use #:local-build? so that it's substitutable.
+                                    #:width #$width
-  (let ((size (string-append (number->string width)
+                                    #:height #$height)))))
-                             "x" (number->string height))))
-    (gexp->derivation "grub-image.resized.png"
-                      #~(zero?
-                         (system* (string-append #$imagemagick "/bin/convert")
-                                  "-resize" #$size #$image #$output)))))
 
 (define* (grub-background-image config #:key (width 1024) (height 768))
   "Return the GRUB background image defined in CONFIG with a ratio of
@@ -160,8 +157,8 @@ WIDTH/HEIGHT, or #f if none was found."
                         (= (grub-image-aspect-ratio image) ratio))
                       (grub-theme-images (grub-configuration-theme config)))))
     (if image
-        (mlet %store-monad ((png (svg->png (grub-image-file image))))
+        (svg->png (grub-image-file image)
-          (resize-image png width height))
+                  #:width width #:height height)
         (with-monad %store-monad
           (return #f)))))